mirror of
https://github.com/mollyim/webrtc.git
synced 2025-05-16 15:20:42 +01:00
e7c79fd3d6
We need to be able build chromium with rtc_include_tests = true. It reveals a lot of targets that are not compatible with chromium but aren't marked so. `rtc_include_tests=true` has been considered a way to disable targets for the Chromium build, causing an overload on rtc_include_tests while the meaning of the two GN args (rtc_include_tests and build_with_chromium) should be kept separated. Bug: webrtc:12404 Change-Id: I2f72825445916eae7c20ef9338672d6a07a9b9ff Reviewed-on: https://webrtc-review.googlesource.com/c/src/+/203890 Reviewed-by: Mirko Bonadei <mbonadei@webrtc.org> Commit-Queue: Andrey Logvin <landrey@webrtc.org> Cr-Commit-Position: refs/heads/master@{#33124}
143 lines
3.5 KiB
Text
143 lines
3.5 KiB
Text
# Copyright (c) 2014 The WebRTC project authors. All Rights Reserved.
|
|
#
|
|
# Use of this source code is governed by a BSD-style license
|
|
# that can be found in the LICENSE file in the root of the source
|
|
# tree. An additional intellectual property rights grant can be found
|
|
# in the file PATENTS. All contributing project authors may
|
|
# be found in the AUTHORS file in the root of the source tree.
|
|
|
|
if (is_android) {
|
|
import("//build/config/android/config.gni")
|
|
import("//build/config/android/rules.gni")
|
|
}
|
|
import("../webrtc.gni")
|
|
|
|
rtc_library("system_wrappers") {
|
|
visibility = [ "*" ]
|
|
sources = [
|
|
"include/clock.h",
|
|
"include/cpu_features_wrapper.h",
|
|
"include/cpu_info.h",
|
|
"include/ntp_time.h",
|
|
"include/rtp_to_ntp_estimator.h",
|
|
"include/sleep.h",
|
|
"source/clock.cc",
|
|
"source/cpu_features.cc",
|
|
"source/cpu_info.cc",
|
|
"source/rtp_to_ntp_estimator.cc",
|
|
"source/sleep.cc",
|
|
]
|
|
|
|
defines = []
|
|
libs = []
|
|
deps = [
|
|
":field_trial",
|
|
"../api:array_view",
|
|
"../api/units:timestamp",
|
|
"../modules:module_api_public",
|
|
"../rtc_base:checks",
|
|
"../rtc_base/synchronization:mutex",
|
|
"../rtc_base/system:arch",
|
|
"../rtc_base/system:rtc_export",
|
|
]
|
|
absl_deps = [ "//third_party/abseil-cpp/absl/types:optional" ]
|
|
|
|
if (is_android) {
|
|
if (build_with_mozilla) {
|
|
include_dirs = [
|
|
"/config/external/nspr",
|
|
"/nsprpub/lib/ds",
|
|
"/nsprpub/pr/include",
|
|
]
|
|
} else {
|
|
sources += [ "source/cpu_features_android.cc" ]
|
|
deps += [ "//third_party/android_sdk:cpu_features" ]
|
|
}
|
|
|
|
libs += [ "log" ]
|
|
}
|
|
|
|
if (is_linux || is_chromeos) {
|
|
if (!build_with_chromium) {
|
|
sources += [ "source/cpu_features_linux.cc" ]
|
|
}
|
|
|
|
libs += [ "rt" ]
|
|
}
|
|
|
|
if (is_win) {
|
|
libs += [ "winmm.lib" ]
|
|
|
|
# Windows needs ../rtc_base due to include of
|
|
# webrtc/rtc_base/win32.h in source/clock.cc.
|
|
deps += [ "../rtc_base:win32" ]
|
|
}
|
|
|
|
deps += [
|
|
"../rtc_base:rtc_base_approved",
|
|
"../rtc_base:rtc_numerics",
|
|
]
|
|
}
|
|
|
|
rtc_library("field_trial") {
|
|
visibility = [ "*" ]
|
|
public = [ "include/field_trial.h" ]
|
|
sources = [ "source/field_trial.cc" ]
|
|
if (rtc_exclude_field_trial_default) {
|
|
defines = [ "WEBRTC_EXCLUDE_FIELD_TRIAL_DEFAULT" ]
|
|
}
|
|
deps = [
|
|
"../rtc_base:checks",
|
|
"../rtc_base:logging",
|
|
"../rtc_base:stringutils",
|
|
]
|
|
absl_deps = [ "//third_party/abseil-cpp/absl/strings" ]
|
|
}
|
|
|
|
rtc_library("metrics") {
|
|
visibility = [ "*" ]
|
|
public = [ "include/metrics.h" ]
|
|
sources = [ "source/metrics.cc" ]
|
|
if (rtc_exclude_metrics_default) {
|
|
defines = [ "WEBRTC_EXCLUDE_METRICS_DEFAULT" ]
|
|
}
|
|
deps = [
|
|
"../rtc_base:checks",
|
|
"../rtc_base:rtc_base_approved",
|
|
"../rtc_base/synchronization:mutex",
|
|
]
|
|
}
|
|
|
|
if (rtc_include_tests && !build_with_chromium) {
|
|
rtc_test("system_wrappers_unittests") {
|
|
testonly = true
|
|
sources = [
|
|
"source/clock_unittest.cc",
|
|
"source/field_trial_unittest.cc",
|
|
"source/metrics_default_unittest.cc",
|
|
"source/metrics_unittest.cc",
|
|
"source/ntp_time_unittest.cc",
|
|
"source/rtp_to_ntp_estimator_unittest.cc",
|
|
]
|
|
|
|
deps = [
|
|
":field_trial",
|
|
":metrics",
|
|
":system_wrappers",
|
|
"../rtc_base:checks",
|
|
"../rtc_base:rtc_base_approved",
|
|
"../test:rtc_expect_death",
|
|
"../test:test_main",
|
|
"../test:test_support",
|
|
"//testing/gtest",
|
|
]
|
|
|
|
absl_deps = [ "//third_party/abseil-cpp/absl/strings" ]
|
|
|
|
if (is_android) {
|
|
deps += [ "//testing/android/native_test:native_test_support" ]
|
|
|
|
shard_timeout = 900
|
|
}
|
|
}
|
|
}
|