mirror of
https://github.com/mollyim/webrtc.git
synced 2025-05-15 06:40:43 +01:00
8909a63aca
This is a reland of 711a31aead
Changes since original landing:
Rename methods only used by tests, mainly via FakeClock,
MessageQueueManager::ProcessAllMessageQueues
--> ProcessAllMessageQueuesForTesting
MessageQueue::IsProcessingMessages
--> IsProcessingMessagesForTesting
Fix the handling of null rtc::Thread::Current() in
ProcessAllMessageQueuesInternal().
Add override Thread::IsProcessingMessagesForTesting() to return false
for the wrapped main thread, unless it's also the current thread. In
tests, the main thread is typically not processing any messages,
but blocked in an Event::Wait().
Original change's description:
> Explicitly wrap main thread in test_main.cc.
>
> Bug: webrtc:9714
> Change-Id: I6ee234f9a0b88b3656a683f2455c3e4b2acf0d54
> Reviewed-on: https://webrtc-review.googlesource.com/97683
> Reviewed-by: Tommi <tommi@webrtc.org>
> Reviewed-by: Karl Wiberg <kwiberg@webrtc.org>
> Commit-Queue: Niels Moller <nisse@webrtc.org>
> Cr-Commit-Position: refs/heads/master@{#24560}
Bug: webrtc:9714
Change-Id: I6f022d46aaf1e28f86f09f2d68c1803b69770126
Reviewed-on: https://webrtc-review.googlesource.com/98060
Reviewed-by: Karl Wiberg <kwiberg@webrtc.org>
Reviewed-by: Tommi <tommi@webrtc.org>
Commit-Queue: Niels Moller <nisse@webrtc.org>
Cr-Commit-Position: refs/heads/master@{#24596}
112 lines
4.3 KiB
Text
112 lines
4.3 KiB
Text
/*
|
|
* Copyright 2018 The WebRTC project authors. All Rights Reserved.
|
|
*
|
|
* Use of this source code is governed by a BSD-style license
|
|
* that can be found in the LICENSE file in the root of the source
|
|
* tree. An additional intellectual property rights grant can be found
|
|
* in the file PATENTS. All contributing project authors may
|
|
* be found in the AUTHORS file in the root of the source tree.
|
|
*/
|
|
|
|
#import <XCTest/XCTest.h>
|
|
#import "sdk/objc/components/audio/RTCAudioSession+Private.h"
|
|
#import "sdk/objc/native/api/audio_device_module.h"
|
|
#import "sdk/objc/native/src/audio/audio_device_ios.h"
|
|
|
|
@interface RTCAudioDeviceTests: XCTestCase {
|
|
rtc::scoped_refptr<webrtc::AudioDeviceModule> _audioDeviceModule;
|
|
std::unique_ptr<webrtc::ios_adm::AudioDeviceIOS> _audio_device;
|
|
}
|
|
|
|
@property(nonatomic) RTCAudioSession *audioSession;
|
|
|
|
@end
|
|
|
|
@implementation RTCAudioDeviceTests
|
|
|
|
@synthesize audioSession = _audioSession;
|
|
|
|
- (void)setUp {
|
|
[super setUp];
|
|
|
|
_audioDeviceModule = webrtc::CreateAudioDeviceModule();
|
|
_audio_device.reset(new webrtc::ios_adm::AudioDeviceIOS());
|
|
self.audioSession = [RTCAudioSession sharedInstance];
|
|
|
|
NSError *error = nil;
|
|
[self.audioSession lockForConfiguration];
|
|
[self.audioSession setCategory:AVAudioSessionCategoryPlayAndRecord
|
|
withOptions:0
|
|
error:&error];
|
|
XCTAssertNil(error);
|
|
|
|
[self.audioSession setMode:AVAudioSessionModeVoiceChat error:&error];
|
|
XCTAssertNil(error);
|
|
|
|
[self.audioSession setActive:YES error:&error];
|
|
XCTAssertNil(error);
|
|
|
|
[self.audioSession unlockForConfiguration];
|
|
}
|
|
|
|
- (void)tearDown {
|
|
_audio_device->Terminate();
|
|
_audio_device.reset(nullptr);
|
|
_audioDeviceModule = nullptr;
|
|
[self.audioSession notifyDidEndInterruptionWithShouldResumeSession:NO];
|
|
|
|
[super tearDown];
|
|
}
|
|
|
|
// Verifies that the AudioDeviceIOS is_interrupted_ flag is reset correctly
|
|
// after an iOS AVAudioSessionInterruptionTypeEnded notification event.
|
|
// AudioDeviceIOS listens to RTCAudioSession interrupted notifications by:
|
|
// - In AudioDeviceIOS.InitPlayOrRecord registers its audio_session_observer_
|
|
// callback with RTCAudioSession's delegate list.
|
|
// - When RTCAudioSession receives an iOS audio interrupted notification, it
|
|
// passes the notification to callbacks in its delegate list which sets
|
|
// AudioDeviceIOS's is_interrupted_ flag to true.
|
|
// - When AudioDeviceIOS.ShutdownPlayOrRecord is called, its
|
|
// audio_session_observer_ callback is removed from RTCAudioSessions's
|
|
// delegate list.
|
|
// So if RTCAudioSession receives an iOS end audio interruption notification,
|
|
// AudioDeviceIOS is not notified as its callback is not in RTCAudioSession's
|
|
// delegate list. This causes AudioDeviceIOS's is_interrupted_ flag to be in
|
|
// the wrong (true) state and the audio session will ignore audio changes.
|
|
// As RTCAudioSession keeps its own interrupted state, the fix is to initialize
|
|
// AudioDeviceIOS's is_interrupted_ flag to RTCAudioSession's isInterrupted
|
|
// flag in AudioDeviceIOS.InitPlayOrRecord.
|
|
- (void)testInterruptedAudioSession {
|
|
XCTAssertTrue(self.audioSession.isActive);
|
|
XCTAssertTrue([self.audioSession.category isEqual:AVAudioSessionCategoryPlayAndRecord] ||
|
|
[self.audioSession.category isEqual:AVAudioSessionCategoryPlayback]);
|
|
XCTAssertEqual(AVAudioSessionModeVoiceChat, self.audioSession.mode);
|
|
|
|
std::unique_ptr<webrtc::AudioDeviceBuffer> audio_buffer;
|
|
audio_buffer.reset(new webrtc::AudioDeviceBuffer());
|
|
_audio_device->AttachAudioBuffer(audio_buffer.get());
|
|
XCTAssertEqual(webrtc::AudioDeviceGeneric::InitStatus::OK, _audio_device->Init());
|
|
XCTAssertEqual(0, _audio_device->InitPlayout());
|
|
XCTAssertEqual(0, _audio_device->StartPlayout());
|
|
|
|
// Force interruption.
|
|
[self.audioSession notifyDidBeginInterruption];
|
|
|
|
// Wait for notification to propagate.
|
|
rtc::MessageQueueManager::ProcessAllMessageQueuesForTesting();
|
|
XCTAssertTrue(_audio_device->IsInterrupted());
|
|
|
|
// Force it for testing.
|
|
_audio_device->StopPlayout();
|
|
|
|
[self.audioSession notifyDidEndInterruptionWithShouldResumeSession:YES];
|
|
// Wait for notification to propagate.
|
|
rtc::MessageQueueManager::ProcessAllMessageQueuesForTesting();
|
|
XCTAssertTrue(_audio_device->IsInterrupted());
|
|
|
|
_audio_device->Init();
|
|
_audio_device->InitPlayout();
|
|
XCTAssertFalse(_audio_device->IsInterrupted());
|
|
}
|
|
|
|
@end
|