mirror of
https://github.com/mollyim/webrtc.git
synced 2025-05-14 22:30:40 +01:00
63ee39d0be
This reverts commit 181ea6e414.
Reason for revert: Breaks downstream project. Kári will help to land it next week.
Original change's description:
> Add a prefix for objc category.
>
> According to the Google Objective-C style [1], category names should
> start with an appropriate prefix. WebRTC has some category definitions
> for system interfaces, but it doesn't use prefixes.
>
> $ otool -ov WebRTC.framework/WebRTC | grep -E "^[0-9a-z]{16} 0x[0-9a-z]+ __OBJC_._CATEGORY" | grep -v "_RTC"
> 0000000002160840 0x217c3c0 __OBJC_$_CATEGORY_UIDevice_$_H264Profile
> 0000000002160850 0x21808b8 __OBJC_$_CATEGORY_AVCaptureSession_$_DevicePosition
> 0000000002160858 0x2180968 __OBJC_$_CATEGORY_NSString_$_StdString
> 0000000002160860 0x21809c8 __OBJC_$_CATEGORY_NSString_$_AbslStringView
>
> To avoid conflicts, prefix the names and methods of those categories.
> Also remove sdk/objc/Framework/Classes/Common/NSString+StdString.h as
> it is not used by any other files.
>
> [1] https://google.github.io/styleguide/objcguide.html#category-naming
>
> Bug: webrtc:13884
> Change-Id: I2cf2742af198ab4e0bfb15c0476d72971e50ceee
> Reviewed-on: https://webrtc-review.googlesource.com/c/src/+/262341
> Reviewed-by: Mirko Bonadei <mbonadei@webrtc.org>
> Reviewed-by: Kári Helgason <kthelgason@webrtc.org>
> Commit-Queue: Daniel.L (Byoungchan) Lee <daniel.l@hpcnt.com>
> Reviewed-by: Artem Titov <titovartem@webrtc.org>
> Cr-Commit-Position: refs/heads/main@{#36880}
Bug: webrtc:13884
Change-Id: I85257088e4a3a62e01ff925ab5e77af83b078ef3
No-Presubmit: true
No-Tree-Checks: true
No-Try: true
Reviewed-on: https://webrtc-review.googlesource.com/c/src/+/262420
Bot-Commit: rubber-stamper@appspot.gserviceaccount.com <rubber-stamper@appspot.gserviceaccount.com>
Commit-Queue: Artem Titov <titovartem@webrtc.org>
Auto-Submit: Artem Titov <titovartem@webrtc.org>
Owners-Override: Artem Titov <titovartem@webrtc.org>
Cr-Commit-Position: refs/heads/main@{#36885}
102 lines
4 KiB
Text
102 lines
4 KiB
Text
/*
|
|
* Copyright 2015 The WebRTC project authors. All Rights Reserved.
|
|
*
|
|
* Use of this source code is governed by a BSD-style license
|
|
* that can be found in the LICENSE file in the root of the source
|
|
* tree. An additional intellectual property rights grant can be found
|
|
* in the file PATENTS. All contributing project authors may
|
|
* be found in the AUTHORS file in the root of the source tree.
|
|
*/
|
|
|
|
#import "RTCPeerConnection+Private.h"
|
|
|
|
#import "RTCLegacyStatsReport+Private.h"
|
|
#import "RTCMediaStreamTrack+Private.h"
|
|
#import "RTCRtpReceiver+Private.h"
|
|
#import "RTCRtpSender+Private.h"
|
|
#import "RTCStatisticsReport+Private.h"
|
|
#import "helpers/NSString+StdString.h"
|
|
|
|
#include "rtc_base/checks.h"
|
|
|
|
namespace webrtc {
|
|
|
|
class StatsCollectorCallbackAdapter : public RTCStatsCollectorCallback {
|
|
public:
|
|
StatsCollectorCallbackAdapter(RTCStatisticsCompletionHandler completion_handler)
|
|
: completion_handler_(completion_handler) {}
|
|
|
|
void OnStatsDelivered(const rtc::scoped_refptr<const RTCStatsReport> &report) override {
|
|
RTC_DCHECK(completion_handler_);
|
|
RTC_OBJC_TYPE(RTCStatisticsReport) *statisticsReport =
|
|
[[RTC_OBJC_TYPE(RTCStatisticsReport) alloc] initWithReport:*report];
|
|
completion_handler_(statisticsReport);
|
|
completion_handler_ = nil;
|
|
}
|
|
|
|
private:
|
|
RTCStatisticsCompletionHandler completion_handler_;
|
|
};
|
|
|
|
class StatsObserverAdapter : public StatsObserver {
|
|
public:
|
|
StatsObserverAdapter(
|
|
void (^completionHandler)(NSArray<RTC_OBJC_TYPE(RTCLegacyStatsReport) *> *stats)) {
|
|
completion_handler_ = completionHandler;
|
|
}
|
|
|
|
~StatsObserverAdapter() override { completion_handler_ = nil; }
|
|
|
|
void OnComplete(const StatsReports& reports) override {
|
|
RTC_DCHECK(completion_handler_);
|
|
NSMutableArray *stats = [NSMutableArray arrayWithCapacity:reports.size()];
|
|
for (const auto* report : reports) {
|
|
RTC_OBJC_TYPE(RTCLegacyStatsReport) *statsReport =
|
|
[[RTC_OBJC_TYPE(RTCLegacyStatsReport) alloc] initWithNativeReport:*report];
|
|
[stats addObject:statsReport];
|
|
}
|
|
completion_handler_(stats);
|
|
completion_handler_ = nil;
|
|
}
|
|
|
|
private:
|
|
void (^completion_handler_)(NSArray<RTC_OBJC_TYPE(RTCLegacyStatsReport) *> *stats);
|
|
};
|
|
} // namespace webrtc
|
|
|
|
@implementation RTC_OBJC_TYPE (RTCPeerConnection)
|
|
(Stats)
|
|
|
|
- (void)statisticsForSender : (RTC_OBJC_TYPE(RTCRtpSender) *)sender completionHandler
|
|
: (RTCStatisticsCompletionHandler)completionHandler {
|
|
rtc::scoped_refptr<webrtc::StatsCollectorCallbackAdapter> collector =
|
|
rtc::make_ref_counted<webrtc::StatsCollectorCallbackAdapter>(completionHandler);
|
|
self.nativePeerConnection->GetStats(sender.nativeRtpSender, collector);
|
|
}
|
|
|
|
- (void)statisticsForReceiver:(RTC_OBJC_TYPE(RTCRtpReceiver) *)receiver
|
|
completionHandler:(RTCStatisticsCompletionHandler)completionHandler {
|
|
rtc::scoped_refptr<webrtc::StatsCollectorCallbackAdapter> collector =
|
|
rtc::make_ref_counted<webrtc::StatsCollectorCallbackAdapter>(completionHandler);
|
|
self.nativePeerConnection->GetStats(receiver.nativeRtpReceiver, collector);
|
|
}
|
|
|
|
- (void)statisticsWithCompletionHandler:(RTCStatisticsCompletionHandler)completionHandler {
|
|
rtc::scoped_refptr<webrtc::StatsCollectorCallbackAdapter> collector =
|
|
rtc::make_ref_counted<webrtc::StatsCollectorCallbackAdapter>(completionHandler);
|
|
self.nativePeerConnection->GetStats(collector.get());
|
|
}
|
|
|
|
- (void)statsForTrack:(RTC_OBJC_TYPE(RTCMediaStreamTrack) *)mediaStreamTrack
|
|
statsOutputLevel:(RTCStatsOutputLevel)statsOutputLevel
|
|
completionHandler:
|
|
(void (^)(NSArray<RTC_OBJC_TYPE(RTCLegacyStatsReport) *> *stats))completionHandler {
|
|
rtc::scoped_refptr<webrtc::StatsObserverAdapter> observer =
|
|
rtc::make_ref_counted<webrtc::StatsObserverAdapter>(completionHandler);
|
|
webrtc::PeerConnectionInterface::StatsOutputLevel nativeOutputLevel =
|
|
[[self class] nativeStatsOutputLevelForLevel:statsOutputLevel];
|
|
self.nativePeerConnection->GetStats(
|
|
observer.get(), mediaStreamTrack.nativeTrack.get(), nativeOutputLevel);
|
|
}
|
|
|
|
@end
|