mirror of
https://github.com/mollyim/webrtc.git
synced 2025-05-14 06:10:40 +01:00
7bca8ca4e2
This CL separates the files under sdk/objc into logical directories, replacing the previous file layout under Framework/. A long term goal is to have some system set up to generate the files under sdk/objc/api (the PeerConnection API wrappers) from the C++ code. In the shorter term the goal is to abstract out shared concepts from these classes in order to make them as uniform as possible. The separation into base/, components/, and helpers/ are to differentiate between the base layer's common protocols, various utilities and the actual platform specific components. The old directory layout that resembled a framework's internal layout is not necessary, since it is generated by the framework target when building it. Bug: webrtc:9627 Change-Id: Ib084fd83f050ae980649ca99e841f4fb0580bd8f Reviewed-on: https://webrtc-review.googlesource.com/94142 Reviewed-by: Kári Helgason <kthelgason@webrtc.org> Reviewed-by: Mirko Bonadei <mbonadei@webrtc.org> Reviewed-by: Rasmus Brandt <brandtr@webrtc.org> Reviewed-by: Henrik Andreassson <henrika@webrtc.org> Commit-Queue: Anders Carlsson <andersc@webrtc.org> Cr-Commit-Position: refs/heads/master@{#24493}
76 lines
2.3 KiB
Text
76 lines
2.3 KiB
Text
/*
|
|
* Copyright 2015 The WebRTC project authors. All Rights Reserved.
|
|
*
|
|
* Use of this source code is governed by a BSD-style license
|
|
* that can be found in the LICENSE file in the root of the source
|
|
* tree. An additional intellectual property rights grant can be found
|
|
* in the file PATENTS. All contributing project authors may
|
|
* be found in the AUTHORS file in the root of the source tree.
|
|
*/
|
|
|
|
#import "RTCIceCandidate+Private.h"
|
|
|
|
#include <memory>
|
|
|
|
#import "base/RTCLogging.h"
|
|
#import "helpers/NSString+StdString.h"
|
|
|
|
@implementation RTCIceCandidate
|
|
|
|
@synthesize sdpMid = _sdpMid;
|
|
@synthesize sdpMLineIndex = _sdpMLineIndex;
|
|
@synthesize sdp = _sdp;
|
|
@synthesize serverUrl = _serverUrl;
|
|
|
|
- (instancetype)initWithSdp:(NSString *)sdp
|
|
sdpMLineIndex:(int)sdpMLineIndex
|
|
sdpMid:(NSString *)sdpMid {
|
|
NSParameterAssert(sdp.length);
|
|
if (self = [super init]) {
|
|
_sdpMid = [sdpMid copy];
|
|
_sdpMLineIndex = sdpMLineIndex;
|
|
_sdp = [sdp copy];
|
|
}
|
|
return self;
|
|
}
|
|
|
|
- (NSString *)description {
|
|
return [NSString stringWithFormat:@"RTCIceCandidate:\n%@\n%d\n%@\n%@",
|
|
_sdpMid,
|
|
_sdpMLineIndex,
|
|
_sdp,
|
|
_serverUrl];
|
|
}
|
|
|
|
#pragma mark - Private
|
|
|
|
- (instancetype)initWithNativeCandidate:
|
|
(const webrtc::IceCandidateInterface *)candidate {
|
|
NSParameterAssert(candidate);
|
|
std::string sdp;
|
|
candidate->ToString(&sdp);
|
|
|
|
RTCIceCandidate *rtcCandidate =
|
|
[self initWithSdp:[NSString stringForStdString:sdp]
|
|
sdpMLineIndex:candidate->sdp_mline_index()
|
|
sdpMid:[NSString stringForStdString:candidate->sdp_mid()]];
|
|
rtcCandidate->_serverUrl = [NSString stringForStdString:candidate->server_url()];
|
|
return rtcCandidate;
|
|
}
|
|
|
|
- (std::unique_ptr<webrtc::IceCandidateInterface>)nativeCandidate {
|
|
webrtc::SdpParseError error;
|
|
|
|
webrtc::IceCandidateInterface *candidate = webrtc::CreateIceCandidate(
|
|
_sdpMid.stdString, _sdpMLineIndex, _sdp.stdString, &error);
|
|
|
|
if (!candidate) {
|
|
RTCLog(@"Failed to create ICE candidate: %s\nline: %s",
|
|
error.description.c_str(),
|
|
error.line.c_str());
|
|
}
|
|
|
|
return std::unique_ptr<webrtc::IceCandidateInterface>(candidate);
|
|
}
|
|
|
|
@end
|