mirror of
https://github.com/mollyim/webrtc.git
synced 2025-05-14 14:20:45 +01:00
7bca8ca4e2
This CL separates the files under sdk/objc into logical directories, replacing the previous file layout under Framework/. A long term goal is to have some system set up to generate the files under sdk/objc/api (the PeerConnection API wrappers) from the C++ code. In the shorter term the goal is to abstract out shared concepts from these classes in order to make them as uniform as possible. The separation into base/, components/, and helpers/ are to differentiate between the base layer's common protocols, various utilities and the actual platform specific components. The old directory layout that resembled a framework's internal layout is not necessary, since it is generated by the framework target when building it. Bug: webrtc:9627 Change-Id: Ib084fd83f050ae980649ca99e841f4fb0580bd8f Reviewed-on: https://webrtc-review.googlesource.com/94142 Reviewed-by: Kári Helgason <kthelgason@webrtc.org> Reviewed-by: Mirko Bonadei <mbonadei@webrtc.org> Reviewed-by: Rasmus Brandt <brandtr@webrtc.org> Reviewed-by: Henrik Andreassson <henrika@webrtc.org> Commit-Queue: Anders Carlsson <andersc@webrtc.org> Cr-Commit-Position: refs/heads/master@{#24493}
113 lines
3.8 KiB
Text
113 lines
3.8 KiB
Text
/*
|
|
* Copyright 2015 The WebRTC project authors. All Rights Reserved.
|
|
*
|
|
* Use of this source code is governed by a BSD-style license
|
|
* that can be found in the LICENSE file in the root of the source
|
|
* tree. An additional intellectual property rights grant can be found
|
|
* in the file PATENTS. All contributing project authors may
|
|
* be found in the AUTHORS file in the root of the source tree.
|
|
*/
|
|
|
|
#import "RTCVideoTrack+Private.h"
|
|
|
|
#import "RTCMediaStreamTrack+Private.h"
|
|
#import "RTCPeerConnectionFactory+Private.h"
|
|
#import "RTCVideoSource+Private.h"
|
|
#import "api/RTCVideoRendererAdapter+Private.h"
|
|
#import "helpers/NSString+StdString.h"
|
|
|
|
@implementation RTCVideoTrack {
|
|
NSMutableArray *_adapters;
|
|
}
|
|
|
|
@synthesize source = _source;
|
|
|
|
- (instancetype)initWithFactory:(RTCPeerConnectionFactory *)factory
|
|
source:(RTCVideoSource *)source
|
|
trackId:(NSString *)trackId {
|
|
NSParameterAssert(factory);
|
|
NSParameterAssert(source);
|
|
NSParameterAssert(trackId.length);
|
|
std::string nativeId = [NSString stdStringForString:trackId];
|
|
rtc::scoped_refptr<webrtc::VideoTrackInterface> track =
|
|
factory.nativeFactory->CreateVideoTrack(nativeId,
|
|
source.nativeVideoSource);
|
|
if (self = [self initWithFactory:factory nativeTrack:track type:RTCMediaStreamTrackTypeVideo]) {
|
|
_source = source;
|
|
}
|
|
return self;
|
|
}
|
|
|
|
- (instancetype)initWithFactory:(RTCPeerConnectionFactory *)factory
|
|
nativeTrack:
|
|
(rtc::scoped_refptr<webrtc::MediaStreamTrackInterface>)nativeMediaTrack
|
|
type:(RTCMediaStreamTrackType)type {
|
|
NSParameterAssert(factory);
|
|
NSParameterAssert(nativeMediaTrack);
|
|
NSParameterAssert(type == RTCMediaStreamTrackTypeVideo);
|
|
if (self = [super initWithFactory:factory nativeTrack:nativeMediaTrack type:type]) {
|
|
_adapters = [NSMutableArray array];
|
|
}
|
|
return self;
|
|
}
|
|
|
|
- (void)dealloc {
|
|
for (RTCVideoRendererAdapter *adapter in _adapters) {
|
|
self.nativeVideoTrack->RemoveSink(adapter.nativeVideoRenderer);
|
|
}
|
|
}
|
|
|
|
- (RTCVideoSource *)source {
|
|
if (!_source) {
|
|
rtc::scoped_refptr<webrtc::VideoTrackSourceInterface> source =
|
|
self.nativeVideoTrack->GetSource();
|
|
if (source) {
|
|
_source =
|
|
[[RTCVideoSource alloc] initWithFactory:self.factory nativeVideoSource:source.get()];
|
|
}
|
|
}
|
|
return _source;
|
|
}
|
|
|
|
- (void)addRenderer:(id<RTCVideoRenderer>)renderer {
|
|
// Make sure we don't have this renderer yet.
|
|
for (RTCVideoRendererAdapter *adapter in _adapters) {
|
|
if (adapter.videoRenderer == renderer) {
|
|
NSAssert(NO, @"|renderer| is already attached to this track");
|
|
return;
|
|
}
|
|
}
|
|
// Create a wrapper that provides a native pointer for us.
|
|
RTCVideoRendererAdapter* adapter =
|
|
[[RTCVideoRendererAdapter alloc] initWithNativeRenderer:renderer];
|
|
[_adapters addObject:adapter];
|
|
self.nativeVideoTrack->AddOrUpdateSink(adapter.nativeVideoRenderer,
|
|
rtc::VideoSinkWants());
|
|
}
|
|
|
|
- (void)removeRenderer:(id<RTCVideoRenderer>)renderer {
|
|
__block NSUInteger indexToRemove = NSNotFound;
|
|
[_adapters enumerateObjectsUsingBlock:^(RTCVideoRendererAdapter *adapter,
|
|
NSUInteger idx,
|
|
BOOL *stop) {
|
|
if (adapter.videoRenderer == renderer) {
|
|
indexToRemove = idx;
|
|
*stop = YES;
|
|
}
|
|
}];
|
|
if (indexToRemove == NSNotFound) {
|
|
return;
|
|
}
|
|
RTCVideoRendererAdapter *adapterToRemove =
|
|
[_adapters objectAtIndex:indexToRemove];
|
|
self.nativeVideoTrack->RemoveSink(adapterToRemove.nativeVideoRenderer);
|
|
[_adapters removeObjectAtIndex:indexToRemove];
|
|
}
|
|
|
|
#pragma mark - Private
|
|
|
|
- (rtc::scoped_refptr<webrtc::VideoTrackInterface>)nativeVideoTrack {
|
|
return static_cast<webrtc::VideoTrackInterface *>(self.nativeTrack.get());
|
|
}
|
|
|
|
@end
|