mirror of
https://github.com/mollyim/webrtc.git
synced 2025-05-14 06:10:40 +01:00
7bca8ca4e2
This CL separates the files under sdk/objc into logical directories, replacing the previous file layout under Framework/. A long term goal is to have some system set up to generate the files under sdk/objc/api (the PeerConnection API wrappers) from the C++ code. In the shorter term the goal is to abstract out shared concepts from these classes in order to make them as uniform as possible. The separation into base/, components/, and helpers/ are to differentiate between the base layer's common protocols, various utilities and the actual platform specific components. The old directory layout that resembled a framework's internal layout is not necessary, since it is generated by the framework target when building it. Bug: webrtc:9627 Change-Id: Ib084fd83f050ae980649ca99e841f4fb0580bd8f Reviewed-on: https://webrtc-review.googlesource.com/94142 Reviewed-by: Kári Helgason <kthelgason@webrtc.org> Reviewed-by: Mirko Bonadei <mbonadei@webrtc.org> Reviewed-by: Rasmus Brandt <brandtr@webrtc.org> Reviewed-by: Henrik Andreassson <henrika@webrtc.org> Commit-Queue: Anders Carlsson <andersc@webrtc.org> Cr-Commit-Position: refs/heads/master@{#24493}
100 lines
3.8 KiB
Text
100 lines
3.8 KiB
Text
/*
|
|
* Copyright 2017 The WebRTC project authors. All Rights Reserved.
|
|
*
|
|
* Use of this source code is governed by a BSD-style license
|
|
* that can be found in the LICENSE file in the root of the source
|
|
* tree. An additional intellectual property rights grant can be found
|
|
* in the file PATENTS. All contributing project authors may
|
|
* be found in the AUTHORS file in the root of the source tree.
|
|
*/
|
|
|
|
#import <Foundation/Foundation.h>
|
|
#import <OCMock/OCMock.h>
|
|
|
|
#include "sdk/objc/native/src/objc_video_decoder_factory.h"
|
|
|
|
#import "base/RTCVideoDecoder.h"
|
|
#import "base/RTCVideoDecoderFactory.h"
|
|
#include "media/base/codec.h"
|
|
#include "modules/include/module_common_types.h"
|
|
#include "modules/video_coding/include/video_codec_interface.h"
|
|
#include "modules/video_coding/include/video_error_codes.h"
|
|
#include "rtc_base/gunit.h"
|
|
|
|
id<RTCVideoDecoderFactory> CreateDecoderFactoryReturning(int return_code) {
|
|
id decoderMock = OCMProtocolMock(@protocol(RTCVideoDecoder));
|
|
OCMStub([decoderMock startDecodeWithNumberOfCores:1]).andReturn(return_code);
|
|
OCMStub([decoderMock decode:[OCMArg any]
|
|
missingFrames:NO
|
|
codecSpecificInfo:[OCMArg any]
|
|
renderTimeMs:0])
|
|
.andReturn(return_code);
|
|
OCMStub([decoderMock releaseDecoder]).andReturn(return_code);
|
|
|
|
id decoderFactoryMock = OCMProtocolMock(@protocol(RTCVideoDecoderFactory));
|
|
RTCVideoCodecInfo *supported = [[RTCVideoCodecInfo alloc] initWithName:@"H264" parameters:nil];
|
|
OCMStub([decoderFactoryMock supportedCodecs]).andReturn(@[ supported ]);
|
|
OCMStub([decoderFactoryMock createDecoder:[OCMArg any]]).andReturn(decoderMock);
|
|
return decoderFactoryMock;
|
|
}
|
|
|
|
id<RTCVideoDecoderFactory> CreateOKDecoderFactory() {
|
|
return CreateDecoderFactoryReturning(WEBRTC_VIDEO_CODEC_OK);
|
|
}
|
|
|
|
id<RTCVideoDecoderFactory> CreateErrorDecoderFactory() {
|
|
return CreateDecoderFactoryReturning(WEBRTC_VIDEO_CODEC_ERROR);
|
|
}
|
|
|
|
std::unique_ptr<webrtc::VideoDecoder> GetObjCDecoder(id<RTCVideoDecoderFactory> factory) {
|
|
webrtc::ObjCVideoDecoderFactory decoder_factory(factory);
|
|
return decoder_factory.CreateVideoDecoder(webrtc::SdpVideoFormat(cricket::kH264CodecName));
|
|
}
|
|
|
|
#pragma mark -
|
|
|
|
TEST(ObjCVideoDecoderFactoryTest, InitDecodeReturnsOKOnSuccess) {
|
|
std::unique_ptr<webrtc::VideoDecoder> decoder = GetObjCDecoder(CreateOKDecoderFactory());
|
|
|
|
auto* settings = new webrtc::VideoCodec();
|
|
EXPECT_EQ(decoder->InitDecode(settings, 1), WEBRTC_VIDEO_CODEC_OK);
|
|
}
|
|
|
|
TEST(ObjCVideoDecoderFactoryTest, InitDecodeReturnsErrorOnFail) {
|
|
std::unique_ptr<webrtc::VideoDecoder> decoder = GetObjCDecoder(CreateErrorDecoderFactory());
|
|
|
|
auto* settings = new webrtc::VideoCodec();
|
|
EXPECT_EQ(decoder->InitDecode(settings, 1), WEBRTC_VIDEO_CODEC_ERROR);
|
|
}
|
|
|
|
TEST(ObjCVideoDecoderFactoryTest, DecodeReturnsOKOnSuccess) {
|
|
std::unique_ptr<webrtc::VideoDecoder> decoder = GetObjCDecoder(CreateOKDecoderFactory());
|
|
|
|
webrtc::EncodedImage encoded_image;
|
|
webrtc::CodecSpecificInfo info;
|
|
info.codecType = webrtc::kVideoCodecH264;
|
|
|
|
EXPECT_EQ(decoder->Decode(encoded_image, false, &info, 0), WEBRTC_VIDEO_CODEC_OK);
|
|
}
|
|
|
|
TEST(ObjCVideoDecoderFactoryTest, DecodeReturnsErrorOnFail) {
|
|
std::unique_ptr<webrtc::VideoDecoder> decoder = GetObjCDecoder(CreateErrorDecoderFactory());
|
|
|
|
webrtc::EncodedImage encoded_image;
|
|
webrtc::CodecSpecificInfo info;
|
|
info.codecType = webrtc::kVideoCodecH264;
|
|
|
|
EXPECT_EQ(decoder->Decode(encoded_image, false, &info, 0), WEBRTC_VIDEO_CODEC_ERROR);
|
|
}
|
|
|
|
TEST(ObjCVideoDecoderFactoryTest, ReleaseDecodeReturnsOKOnSuccess) {
|
|
std::unique_ptr<webrtc::VideoDecoder> decoder = GetObjCDecoder(CreateOKDecoderFactory());
|
|
|
|
EXPECT_EQ(decoder->Release(), WEBRTC_VIDEO_CODEC_OK);
|
|
}
|
|
|
|
TEST(ObjCVideoDecoderFactoryTest, ReleaseDecodeReturnsErrorOnFail) {
|
|
std::unique_ptr<webrtc::VideoDecoder> decoder = GetObjCDecoder(CreateErrorDecoderFactory());
|
|
|
|
EXPECT_EQ(decoder->Release(), WEBRTC_VIDEO_CODEC_ERROR);
|
|
}
|