mirror of
https://github.com/mollyim/webrtc.git
synced 2025-05-17 15:47:53 +01:00
7bca8ca4e2
This CL separates the files under sdk/objc into logical directories, replacing the previous file layout under Framework/. A long term goal is to have some system set up to generate the files under sdk/objc/api (the PeerConnection API wrappers) from the C++ code. In the shorter term the goal is to abstract out shared concepts from these classes in order to make them as uniform as possible. The separation into base/, components/, and helpers/ are to differentiate between the base layer's common protocols, various utilities and the actual platform specific components. The old directory layout that resembled a framework's internal layout is not necessary, since it is generated by the framework target when building it. Bug: webrtc:9627 Change-Id: Ib084fd83f050ae980649ca99e841f4fb0580bd8f Reviewed-on: https://webrtc-review.googlesource.com/94142 Reviewed-by: Kári Helgason <kthelgason@webrtc.org> Reviewed-by: Mirko Bonadei <mbonadei@webrtc.org> Reviewed-by: Rasmus Brandt <brandtr@webrtc.org> Reviewed-by: Henrik Andreassson <henrika@webrtc.org> Commit-Queue: Anders Carlsson <andersc@webrtc.org> Cr-Commit-Position: refs/heads/master@{#24493}
71 lines
2.5 KiB
Text
71 lines
2.5 KiB
Text
/*
|
|
* Copyright 2018 The WebRTC project authors. All Rights Reserved.
|
|
*
|
|
* Use of this source code is governed by a BSD-style license
|
|
* that can be found in the LICENSE file in the root of the source
|
|
* tree. An additional intellectual property rights grant can be found
|
|
* in the file PATENTS. All contributing project authors may
|
|
* be found in the AUTHORS file in the root of the source tree.
|
|
*/
|
|
|
|
#import "RTCCertificate.h"
|
|
|
|
#import "base/RTCLogging.h"
|
|
|
|
#include "rtc_base/logging.h"
|
|
#include "rtc_base/rtccertificategenerator.h"
|
|
#include "rtc_base/sslidentity.h"
|
|
|
|
@implementation RTCCertificate
|
|
|
|
@synthesize private_key = _private_key;
|
|
@synthesize certificate = _certificate;
|
|
|
|
- (id)copyWithZone:(NSZone *)zone {
|
|
id copy = [[[self class] alloc] initWithPrivateKey:[self.private_key copyWithZone:zone]
|
|
certificate:[self.certificate copyWithZone:zone]];
|
|
return copy;
|
|
}
|
|
|
|
- (instancetype)initWithPrivateKey:(NSString *)private_key certificate:(NSString *)certificate {
|
|
if (self = [super init]) {
|
|
_private_key = [private_key copy];
|
|
_certificate = [certificate copy];
|
|
}
|
|
return self;
|
|
}
|
|
|
|
+ (nullable RTCCertificate *)generateCertificateWithParams:(NSDictionary *)params {
|
|
rtc::KeyType keyType = rtc::KT_ECDSA;
|
|
NSString *keyTypeString = [params valueForKey:@"name"];
|
|
if (keyTypeString && [keyTypeString isEqualToString:@"RSASSA-PKCS1-v1_5"]) {
|
|
keyType = rtc::KT_RSA;
|
|
}
|
|
|
|
NSNumber *expires = [params valueForKey:@"expires"];
|
|
rtc::scoped_refptr<rtc::RTCCertificate> cc_certificate = nullptr;
|
|
if (expires != nil) {
|
|
uint64_t expirationTimestamp = [expires unsignedLongLongValue];
|
|
cc_certificate = rtc::RTCCertificateGenerator::GenerateCertificate(rtc::KeyParams(keyType),
|
|
expirationTimestamp);
|
|
} else {
|
|
cc_certificate =
|
|
rtc::RTCCertificateGenerator::GenerateCertificate(rtc::KeyParams(keyType), absl::nullopt);
|
|
}
|
|
if (!cc_certificate) {
|
|
RTCLogError(@"Failed to generate certificate.");
|
|
return nullptr;
|
|
}
|
|
// grab PEMs and create an NS RTCCerticicate
|
|
rtc::RTCCertificatePEM pem = cc_certificate->ToPEM();
|
|
std::string pem_private_key = pem.private_key();
|
|
std::string pem_certificate = pem.certificate();
|
|
RTC_LOG(LS_INFO) << "CERT PEM ";
|
|
RTC_LOG(LS_INFO) << pem_certificate;
|
|
|
|
RTCCertificate *cert = [[RTCCertificate alloc] initWithPrivateKey:@(pem_private_key.c_str())
|
|
certificate:@(pem_certificate.c_str())];
|
|
return cert;
|
|
}
|
|
|
|
@end
|