mirror of
https://github.com/mollyim/webrtc.git
synced 2025-05-13 05:40:42 +01:00
ac0d18341d
Updates all webrtc code, to have a small followup cl to just add the "explicit" keyword. Patchset #24 passed all webrtc tests, with explicit. Bug: webrtc:13464 Change-Id: I39863d3752f73209b531120f66916dc9177bf63a Reviewed-on: https://webrtc-review.googlesource.com/c/src/+/242363 Reviewed-by: Tomas Gunnarsson <tommi@webrtc.org> Commit-Queue: Niels Moller <nisse@webrtc.org> Cr-Commit-Position: refs/heads/main@{#35718}
67 lines
2.3 KiB
Text
67 lines
2.3 KiB
Text
/*
|
|
* Copyright 2015 The WebRTC project authors. All Rights Reserved.
|
|
*
|
|
* Use of this source code is governed by a BSD-style license
|
|
* that can be found in the LICENSE file in the root of the source
|
|
* tree. An additional intellectual property rights grant can be found
|
|
* in the file PATENTS. All contributing project authors may
|
|
* be found in the AUTHORS file in the root of the source tree.
|
|
*/
|
|
|
|
#import "RTCAudioTrack+Private.h"
|
|
|
|
#import "RTCAudioSource+Private.h"
|
|
#import "RTCMediaStreamTrack+Private.h"
|
|
#import "RTCPeerConnectionFactory+Private.h"
|
|
#import "helpers/NSString+StdString.h"
|
|
|
|
#include "rtc_base/checks.h"
|
|
|
|
@implementation RTC_OBJC_TYPE (RTCAudioTrack)
|
|
|
|
@synthesize source = _source;
|
|
|
|
- (instancetype)initWithFactory:(RTC_OBJC_TYPE(RTCPeerConnectionFactory) *)factory
|
|
source:(RTC_OBJC_TYPE(RTCAudioSource) *)source
|
|
trackId:(NSString *)trackId {
|
|
RTC_DCHECK(factory);
|
|
RTC_DCHECK(source);
|
|
RTC_DCHECK(trackId.length);
|
|
|
|
std::string nativeId = [NSString stdStringForString:trackId];
|
|
rtc::scoped_refptr<webrtc::AudioTrackInterface> track =
|
|
factory.nativeFactory->CreateAudioTrack(nativeId, source.nativeAudioSource);
|
|
if (self = [self initWithFactory:factory nativeTrack:track type:RTCMediaStreamTrackTypeAudio]) {
|
|
_source = source;
|
|
}
|
|
return self;
|
|
}
|
|
|
|
- (instancetype)initWithFactory:(RTC_OBJC_TYPE(RTCPeerConnectionFactory) *)factory
|
|
nativeTrack:(rtc::scoped_refptr<webrtc::MediaStreamTrackInterface>)nativeTrack
|
|
type:(RTCMediaStreamTrackType)type {
|
|
NSParameterAssert(factory);
|
|
NSParameterAssert(nativeTrack);
|
|
NSParameterAssert(type == RTCMediaStreamTrackTypeAudio);
|
|
return [super initWithFactory:factory nativeTrack:nativeTrack type:type];
|
|
}
|
|
|
|
- (RTC_OBJC_TYPE(RTCAudioSource) *)source {
|
|
if (!_source) {
|
|
rtc::scoped_refptr<webrtc::AudioSourceInterface> source(self.nativeAudioTrack->GetSource());
|
|
if (source) {
|
|
_source = [[RTC_OBJC_TYPE(RTCAudioSource) alloc] initWithFactory:self.factory
|
|
nativeAudioSource:source];
|
|
}
|
|
}
|
|
return _source;
|
|
}
|
|
|
|
#pragma mark - Private
|
|
|
|
- (rtc::scoped_refptr<webrtc::AudioTrackInterface>)nativeAudioTrack {
|
|
return rtc::scoped_refptr<webrtc::AudioTrackInterface>(
|
|
static_cast<webrtc::AudioTrackInterface *>(self.nativeTrack.get()));
|
|
}
|
|
|
|
@end
|