mirror of
https://github.com/mollyim/webrtc.git
synced 2025-05-14 14:20:45 +01:00
7bca8ca4e2
This CL separates the files under sdk/objc into logical directories, replacing the previous file layout under Framework/. A long term goal is to have some system set up to generate the files under sdk/objc/api (the PeerConnection API wrappers) from the C++ code. In the shorter term the goal is to abstract out shared concepts from these classes in order to make them as uniform as possible. The separation into base/, components/, and helpers/ are to differentiate between the base layer's common protocols, various utilities and the actual platform specific components. The old directory layout that resembled a framework's internal layout is not necessary, since it is generated by the framework target when building it. Bug: webrtc:9627 Change-Id: Ib084fd83f050ae980649ca99e841f4fb0580bd8f Reviewed-on: https://webrtc-review.googlesource.com/94142 Reviewed-by: Kári Helgason <kthelgason@webrtc.org> Reviewed-by: Mirko Bonadei <mbonadei@webrtc.org> Reviewed-by: Rasmus Brandt <brandtr@webrtc.org> Reviewed-by: Henrik Andreassson <henrika@webrtc.org> Commit-Queue: Anders Carlsson <andersc@webrtc.org> Cr-Commit-Position: refs/heads/master@{#24493}
60 lines
1.9 KiB
Text
60 lines
1.9 KiB
Text
/*
|
|
* Copyright 2015 The WebRTC project authors. All Rights Reserved.
|
|
*
|
|
* Use of this source code is governed by a BSD-style license
|
|
* that can be found in the LICENSE file in the root of the source
|
|
* tree. An additional intellectual property rights grant can be found
|
|
* in the file PATENTS. All contributing project authors may
|
|
* be found in the AUTHORS file in the root of the source tree.
|
|
*/
|
|
|
|
#import "RTCLegacyStatsReport+Private.h"
|
|
|
|
#import "base/RTCLogging.h"
|
|
#import "helpers/NSString+StdString.h"
|
|
|
|
#include "rtc_base/checks.h"
|
|
|
|
@implementation RTCLegacyStatsReport
|
|
|
|
@synthesize timestamp = _timestamp;
|
|
@synthesize type = _type;
|
|
@synthesize reportId = _reportId;
|
|
@synthesize values = _values;
|
|
|
|
- (NSString *)description {
|
|
return [NSString stringWithFormat:@"RTCLegacyStatsReport:\n%@\n%@\n%f\n%@",
|
|
_reportId,
|
|
_type,
|
|
_timestamp,
|
|
_values];
|
|
}
|
|
|
|
#pragma mark - Private
|
|
|
|
- (instancetype)initWithNativeReport:(const webrtc::StatsReport &)nativeReport {
|
|
if (self = [super init]) {
|
|
_timestamp = nativeReport.timestamp();
|
|
_type = [NSString stringForStdString:nativeReport.TypeToString()];
|
|
_reportId = [NSString stringForStdString:
|
|
nativeReport.id()->ToString()];
|
|
|
|
NSUInteger capacity = nativeReport.values().size();
|
|
NSMutableDictionary *values =
|
|
[NSMutableDictionary dictionaryWithCapacity:capacity];
|
|
for (auto const &valuePair : nativeReport.values()) {
|
|
NSString *key = [NSString stringForStdString:
|
|
valuePair.second->display_name()];
|
|
NSString *value = [NSString stringForStdString:
|
|
valuePair.second->ToString()];
|
|
|
|
// Not expecting duplicate keys.
|
|
RTC_DCHECK(![values objectForKey:key]);
|
|
[values setObject:value forKey:key];
|
|
}
|
|
_values = values;
|
|
}
|
|
return self;
|
|
}
|
|
|
|
@end
|