mirror of
https://github.com/mollyim/webrtc.git
synced 2025-05-14 14:20:45 +01:00
92ea95e34a
In https://webrtc-review.googlesource.com/c/src/+/1560 we moved WebRTC from src/webrtc to src/ (in order to preserve an healthy git history). This CL takes care of fixing header guards, #include paths, etc... NOPRESUBMIT=true NOTREECHECKS=true NOTRY=true TBR=tommi@webrtc.org Bug: chromium:611808 Change-Id: Iea91618212bee0af16aa3f05071eab8f93706578 Reviewed-on: https://webrtc-review.googlesource.com/1561 Reviewed-by: Mirko Bonadei <mbonadei@webrtc.org> Reviewed-by: Henrik Kjellander <kjellander@webrtc.org> Commit-Queue: Mirko Bonadei <mbonadei@webrtc.org> Cr-Commit-Position: refs/heads/master@{#19846}
73 lines
1.9 KiB
Text
73 lines
1.9 KiB
Text
/*
|
|
* Copyright (c) 2013 The WebRTC project authors. All Rights Reserved.
|
|
*
|
|
* Use of this source code is governed by a BSD-style license
|
|
* that can be found in the LICENSE file in the root of the source
|
|
* tree. An additional intellectual property rights grant can be found
|
|
* in the file PATENTS. All contributing project authors may
|
|
* be found in the AUTHORS file in the root of the source tree.
|
|
*/
|
|
|
|
#import <Cocoa/Cocoa.h>
|
|
|
|
#include "test/run_test.h"
|
|
|
|
// Converting a C++ function pointer to an Objective-C block.
|
|
typedef void(^TestBlock)();
|
|
TestBlock functionToBlock(void(*function)()) {
|
|
return [^(void) { function(); } copy];
|
|
}
|
|
|
|
// Class calling the test function on the platform specific thread.
|
|
@interface TestRunner : NSObject {
|
|
BOOL running_;
|
|
}
|
|
- (void)runAllTests:(TestBlock)ignored;
|
|
- (BOOL)running;
|
|
@end
|
|
|
|
@implementation TestRunner
|
|
- (id)init {
|
|
self = [super init];
|
|
if (self) {
|
|
running_ = YES;
|
|
}
|
|
return self;
|
|
}
|
|
|
|
- (void)runAllTests:(TestBlock)testBlock {
|
|
@autoreleasepool {
|
|
testBlock();
|
|
running_ = NO;
|
|
}
|
|
}
|
|
|
|
- (BOOL)running {
|
|
return running_;
|
|
}
|
|
@end
|
|
|
|
namespace webrtc {
|
|
namespace test {
|
|
|
|
void RunTest(void(*test)()) {
|
|
@autoreleasepool {
|
|
[NSApplication sharedApplication];
|
|
|
|
// Convert the function pointer to an Objective-C block and call on a
|
|
// separate thread, to avoid blocking the main thread.
|
|
TestRunner *testRunner = [[TestRunner alloc] init];
|
|
TestBlock testBlock = functionToBlock(test);
|
|
[NSThread detachNewThreadSelector:@selector(runAllTests:)
|
|
toTarget:testRunner
|
|
withObject:testBlock];
|
|
|
|
NSRunLoop *runLoop = [NSRunLoop currentRunLoop];
|
|
while ([testRunner running] && [runLoop runMode:NSDefaultRunLoopMode
|
|
beforeDate:[NSDate dateWithTimeIntervalSinceNow:0.1]])
|
|
;
|
|
}
|
|
}
|
|
|
|
} // namespace test
|
|
} // namespace webrtc
|