mirror of
https://github.com/mollyim/webrtc.git
synced 2025-05-13 22:00:47 +01:00
86d053c2db
Static libraries don't guarantee that an exported symbol gets linked into a shared library (and in order to support Chromium's component build mode, WebRTC needs to be linked as a shared library). Source sets always pass all the object files to the linker. On the flip side, source_sets link more object files in release builds and to avoid this, this CL introduces a the GN template "rtc_library" that expands to static_library during release builds and to source_set during component builds. See: https://gn.googlesource.com/gn/+/master/docs/reference.md#func_source_set Bug: webrtc:9419 Change-Id: I4667e820c2b3fcec417becbd2034acc13e4f04fe Reviewed-on: https://webrtc-review.googlesource.com/c/src/+/157168 Commit-Queue: Mirko Bonadei <mbonadei@webrtc.org> Reviewed-by: Karl Wiberg <kwiberg@webrtc.org> Reviewed-by: Nico Weber <thakis@chromium.org> Cr-Commit-Position: refs/heads/master@{#29525}
156 lines
3.4 KiB
Text
156 lines
3.4 KiB
Text
# Copyright (c) 2014 The WebRTC project authors. All Rights Reserved.
|
|
#
|
|
# Use of this source code is governed by a BSD-style license
|
|
# that can be found in the LICENSE file in the root of the source
|
|
# tree. An additional intellectual property rights grant can be found
|
|
# in the file PATENTS. All contributing project authors may
|
|
# be found in the AUTHORS file in the root of the source tree.
|
|
|
|
import("../../../webrtc.gni")
|
|
|
|
rtc_library("cascaded_biquad_filter") {
|
|
sources = [
|
|
"cascaded_biquad_filter.cc",
|
|
"cascaded_biquad_filter.h",
|
|
]
|
|
deps = [
|
|
"../../../api:array_view",
|
|
"../../../rtc_base:checks",
|
|
]
|
|
}
|
|
|
|
rtc_library("block_mean_calculator") {
|
|
sources = [
|
|
"block_mean_calculator.cc",
|
|
"block_mean_calculator.h",
|
|
]
|
|
deps = [
|
|
"../../../rtc_base:checks",
|
|
"../../../rtc_base:rtc_base_approved",
|
|
]
|
|
}
|
|
|
|
rtc_library("legacy_delay_estimator") {
|
|
sources = [
|
|
"delay_estimator.cc",
|
|
"delay_estimator.h",
|
|
"delay_estimator_internal.h",
|
|
"delay_estimator_wrapper.cc",
|
|
"delay_estimator_wrapper.h",
|
|
]
|
|
deps = [
|
|
"../../../rtc_base:checks",
|
|
]
|
|
}
|
|
|
|
rtc_library("ooura_fft") {
|
|
sources = [
|
|
"ooura_fft.cc",
|
|
"ooura_fft.h",
|
|
"ooura_fft_tables_common.h",
|
|
]
|
|
deps = [
|
|
"../../../rtc_base/system:arch",
|
|
"../../../system_wrappers:cpu_features_api",
|
|
]
|
|
cflags = []
|
|
|
|
if (current_cpu == "x86" || current_cpu == "x64") {
|
|
sources += [
|
|
"ooura_fft_sse2.cc",
|
|
"ooura_fft_tables_neon_sse2.h",
|
|
]
|
|
if (is_posix || is_fuchsia) {
|
|
cflags += [ "-msse2" ]
|
|
}
|
|
}
|
|
|
|
if (rtc_build_with_neon) {
|
|
sources += [
|
|
"ooura_fft_neon.cc",
|
|
"ooura_fft_tables_neon_sse2.h",
|
|
]
|
|
|
|
deps += [ "../../../common_audio" ]
|
|
|
|
if (current_cpu != "arm64") {
|
|
# Enable compilation for the NEON instruction set.
|
|
suppressed_configs += [ "//build/config/compiler:compiler_arm_fpu" ]
|
|
cflags += [ "-mfpu=neon" ]
|
|
}
|
|
}
|
|
|
|
if (current_cpu == "mipsel" && mips_float_abi == "hard") {
|
|
sources += [ "ooura_fft_mips.cc" ]
|
|
}
|
|
}
|
|
|
|
rtc_library("pffft_wrapper") {
|
|
visibility = [ "../*" ]
|
|
sources = [
|
|
"pffft_wrapper.cc",
|
|
"pffft_wrapper.h",
|
|
]
|
|
deps = [
|
|
"../../../api:array_view",
|
|
"../../../rtc_base:checks",
|
|
"//third_party/pffft",
|
|
]
|
|
}
|
|
|
|
if (rtc_include_tests) {
|
|
rtc_library("cascaded_biquad_filter_unittest") {
|
|
testonly = true
|
|
|
|
sources = [
|
|
"cascaded_biquad_filter_unittest.cc",
|
|
]
|
|
deps = [
|
|
":cascaded_biquad_filter",
|
|
"../../../rtc_base:rtc_base_approved",
|
|
"../../../test:test_support",
|
|
"//testing/gtest",
|
|
]
|
|
}
|
|
|
|
rtc_library("block_mean_calculator_unittest") {
|
|
testonly = true
|
|
|
|
sources = [
|
|
"block_mean_calculator_unittest.cc",
|
|
]
|
|
deps = [
|
|
":block_mean_calculator",
|
|
"../../../rtc_base:rtc_base_approved",
|
|
"../../../test:test_support",
|
|
"//testing/gtest",
|
|
]
|
|
}
|
|
|
|
rtc_library("legacy_delay_estimator_unittest") {
|
|
testonly = true
|
|
|
|
sources = [
|
|
"delay_estimator_unittest.cc",
|
|
]
|
|
deps = [
|
|
":legacy_delay_estimator",
|
|
"../../../rtc_base:rtc_base_approved",
|
|
"../../../test:test_support",
|
|
"//testing/gtest",
|
|
]
|
|
}
|
|
|
|
rtc_library("pffft_wrapper_unittest") {
|
|
testonly = true
|
|
sources = [
|
|
"pffft_wrapper_unittest.cc",
|
|
]
|
|
deps = [
|
|
":pffft_wrapper",
|
|
"../../../test:test_support",
|
|
"//testing/gtest",
|
|
"//third_party/pffft",
|
|
]
|
|
}
|
|
}
|