mirror of
https://github.com/mollyim/webrtc.git
synced 2025-05-13 13:50:40 +01:00
c8a6fb2bb8
The tests in rtc_unittests_objc are old gtest based tests and The tests in sdk_unittests are XCTest based tests. The objc tests in rtc_unittest are causing problems [1], so I think it's time to combine the two types of objc tests. Renaming the files to match the existing sdk_unittests and removing the use of gtest helper functions (eg, EXPECT_EQ) are planned for follow-up CLs. [1] https://webrtc-review.googlesource.com/c/src/+/261724/9 Bug: webrtc:8382 Change-Id: I9308b35f654c4479c9df72bf7cd7f4032e267eb2 Reviewed-on: https://webrtc-review.googlesource.com/c/src/+/262380 Reviewed-by: Mirko Bonadei <mbonadei@webrtc.org> Commit-Queue: Daniel.L (Byoungchan) Lee <daniel.l@hpcnt.com> Reviewed-by: Kári Helgason <kthelgason@webrtc.org> Cr-Commit-Position: refs/heads/main@{#36878}
107 lines
3.9 KiB
Text
107 lines
3.9 KiB
Text
/*
|
|
* Copyright 2017 The WebRTC project authors. All Rights Reserved.
|
|
*
|
|
* Use of this source code is governed by a BSD-style license
|
|
* that can be found in the LICENSE file in the root of the source
|
|
* tree. An additional intellectual property rights grant can be found
|
|
* in the file PATENTS. All contributing project authors may
|
|
* be found in the AUTHORS file in the root of the source tree.
|
|
*/
|
|
|
|
#import <Foundation/Foundation.h>
|
|
#import <OCMock/OCMock.h>
|
|
#import <XCTest/XCTest.h>
|
|
|
|
#include "sdk/objc/native/src/objc_video_decoder_factory.h"
|
|
|
|
#import "base/RTCMacros.h"
|
|
#import "base/RTCVideoDecoder.h"
|
|
#import "base/RTCVideoDecoderFactory.h"
|
|
#include "media/base/codec.h"
|
|
#include "modules/video_coding/include/video_codec_interface.h"
|
|
#include "modules/video_coding/include/video_error_codes.h"
|
|
#include "rtc_base/gunit.h"
|
|
|
|
id<RTC_OBJC_TYPE(RTCVideoDecoderFactory)> CreateDecoderFactoryReturning(int return_code) {
|
|
id decoderMock = OCMProtocolMock(@protocol(RTC_OBJC_TYPE(RTCVideoDecoder)));
|
|
OCMStub([decoderMock startDecodeWithNumberOfCores:1]).andReturn(return_code);
|
|
OCMStub([decoderMock decode:[OCMArg any]
|
|
missingFrames:NO
|
|
codecSpecificInfo:[OCMArg any]
|
|
renderTimeMs:0])
|
|
.andReturn(return_code);
|
|
OCMStub([decoderMock releaseDecoder]).andReturn(return_code);
|
|
|
|
id decoderFactoryMock = OCMProtocolMock(@protocol(RTC_OBJC_TYPE(RTCVideoDecoderFactory)));
|
|
RTC_OBJC_TYPE(RTCVideoCodecInfo)* supported =
|
|
[[RTC_OBJC_TYPE(RTCVideoCodecInfo) alloc] initWithName:@"H264" parameters:nil];
|
|
OCMStub([decoderFactoryMock supportedCodecs]).andReturn(@[ supported ]);
|
|
OCMStub([decoderFactoryMock createDecoder:[OCMArg any]]).andReturn(decoderMock);
|
|
return decoderFactoryMock;
|
|
}
|
|
|
|
id<RTC_OBJC_TYPE(RTCVideoDecoderFactory)> CreateOKDecoderFactory() {
|
|
return CreateDecoderFactoryReturning(WEBRTC_VIDEO_CODEC_OK);
|
|
}
|
|
|
|
id<RTC_OBJC_TYPE(RTCVideoDecoderFactory)> CreateErrorDecoderFactory() {
|
|
return CreateDecoderFactoryReturning(WEBRTC_VIDEO_CODEC_ERROR);
|
|
}
|
|
|
|
std::unique_ptr<webrtc::VideoDecoder> GetObjCDecoder(
|
|
id<RTC_OBJC_TYPE(RTCVideoDecoderFactory)> factory) {
|
|
webrtc::ObjCVideoDecoderFactory decoder_factory(factory);
|
|
return decoder_factory.CreateVideoDecoder(webrtc::SdpVideoFormat(cricket::kH264CodecName));
|
|
}
|
|
|
|
#pragma mark -
|
|
|
|
@interface ObjCVideoDecoderFactoryTests : XCTestCase
|
|
@end
|
|
|
|
@implementation ObjCVideoDecoderFactoryTests
|
|
|
|
- (void)testConfigureReturnsTrueOnSuccess {
|
|
std::unique_ptr<webrtc::VideoDecoder> decoder = GetObjCDecoder(CreateOKDecoderFactory());
|
|
|
|
webrtc::VideoDecoder::Settings settings;
|
|
EXPECT_TRUE(decoder->Configure(settings));
|
|
}
|
|
|
|
- (void)testConfigureReturnsFalseOnFail {
|
|
std::unique_ptr<webrtc::VideoDecoder> decoder = GetObjCDecoder(CreateErrorDecoderFactory());
|
|
|
|
webrtc::VideoDecoder::Settings settings;
|
|
EXPECT_FALSE(decoder->Configure(settings));
|
|
}
|
|
|
|
- (void)testDecodeReturnsOKOnSuccess {
|
|
std::unique_ptr<webrtc::VideoDecoder> decoder = GetObjCDecoder(CreateOKDecoderFactory());
|
|
|
|
webrtc::EncodedImage encoded_image;
|
|
encoded_image.SetEncodedData(webrtc::EncodedImageBuffer::Create());
|
|
|
|
EXPECT_EQ(decoder->Decode(encoded_image, false, 0), WEBRTC_VIDEO_CODEC_OK);
|
|
}
|
|
|
|
- (void)testDecodeReturnsErrorOnFail {
|
|
std::unique_ptr<webrtc::VideoDecoder> decoder = GetObjCDecoder(CreateErrorDecoderFactory());
|
|
|
|
webrtc::EncodedImage encoded_image;
|
|
encoded_image.SetEncodedData(webrtc::EncodedImageBuffer::Create());
|
|
|
|
EXPECT_EQ(decoder->Decode(encoded_image, false, 0), WEBRTC_VIDEO_CODEC_ERROR);
|
|
}
|
|
|
|
- (void)testReleaseDecodeReturnsOKOnSuccess {
|
|
std::unique_ptr<webrtc::VideoDecoder> decoder = GetObjCDecoder(CreateOKDecoderFactory());
|
|
|
|
EXPECT_EQ(decoder->Release(), WEBRTC_VIDEO_CODEC_OK);
|
|
}
|
|
|
|
- (void)testReleaseDecodeReturnsErrorOnFail {
|
|
std::unique_ptr<webrtc::VideoDecoder> decoder = GetObjCDecoder(CreateErrorDecoderFactory());
|
|
|
|
EXPECT_EQ(decoder->Release(), WEBRTC_VIDEO_CODEC_ERROR);
|
|
}
|
|
@end
|