mirror of
https://github.com/mollyim/webrtc.git
synced 2025-05-14 14:20:45 +01:00
17aff35e1d
This CL removes //build/config/clang:find_bad_constructs from the suppressed_configs list, which means that clang:find_bad_constructs is now enabled on these translation units. Bug: webrtc:9251, webrtc:163 Change-Id: I6f03c46e772ccf4d15951a4b9d4e12015d539e58 Reviewed-on: https://webrtc-review.googlesource.com/90408 Reviewed-by: Fredrik Solenberg <solenberg@webrtc.org> Reviewed-by: Kári Helgason <kthelgason@webrtc.org> Commit-Queue: Mirko Bonadei <mbonadei@webrtc.org> Cr-Commit-Position: refs/heads/master@{#24113}
62 lines
2.1 KiB
Text
62 lines
2.1 KiB
Text
/*
|
|
* Copyright 2015 The WebRTC project authors. All Rights Reserved.
|
|
*
|
|
* Use of this source code is governed by a BSD-style license
|
|
* that can be found in the LICENSE file in the root of the source
|
|
* tree. An additional intellectual property rights grant can be found
|
|
* in the file PATENTS. All contributing project authors may
|
|
* be found in the AUTHORS file in the root of the source tree.
|
|
*/
|
|
|
|
#import "RTCPeerConnection+Private.h"
|
|
|
|
#import "NSString+StdString.h"
|
|
#import "RTCMediaStreamTrack+Private.h"
|
|
#import "RTCLegacyStatsReport+Private.h"
|
|
|
|
#include "rtc_base/checks.h"
|
|
|
|
namespace webrtc {
|
|
|
|
class StatsObserverAdapter : public StatsObserver {
|
|
public:
|
|
StatsObserverAdapter(void (^completionHandler)
|
|
(NSArray<RTCLegacyStatsReport *> *stats)) {
|
|
completion_handler_ = completionHandler;
|
|
}
|
|
|
|
~StatsObserverAdapter() override { completion_handler_ = nil; }
|
|
|
|
void OnComplete(const StatsReports& reports) override {
|
|
RTC_DCHECK(completion_handler_);
|
|
NSMutableArray *stats = [NSMutableArray arrayWithCapacity:reports.size()];
|
|
for (const auto* report : reports) {
|
|
RTCLegacyStatsReport *statsReport =
|
|
[[RTCLegacyStatsReport alloc] initWithNativeReport:*report];
|
|
[stats addObject:statsReport];
|
|
}
|
|
completion_handler_(stats);
|
|
completion_handler_ = nil;
|
|
}
|
|
|
|
private:
|
|
void (^completion_handler_)(NSArray<RTCLegacyStatsReport *> *stats);
|
|
};
|
|
} // namespace webrtc
|
|
|
|
@implementation RTCPeerConnection (Stats)
|
|
|
|
- (void)statsForTrack:(RTCMediaStreamTrack *)mediaStreamTrack
|
|
statsOutputLevel:(RTCStatsOutputLevel)statsOutputLevel
|
|
completionHandler:
|
|
(void (^)(NSArray<RTCLegacyStatsReport *> *stats))completionHandler {
|
|
rtc::scoped_refptr<webrtc::StatsObserverAdapter> observer(
|
|
new rtc::RefCountedObject<webrtc::StatsObserverAdapter>
|
|
(completionHandler));
|
|
webrtc::PeerConnectionInterface::StatsOutputLevel nativeOutputLevel =
|
|
[[self class] nativeStatsOutputLevelForLevel:statsOutputLevel];
|
|
self.nativePeerConnection->GetStats(
|
|
observer, mediaStreamTrack.nativeTrack, nativeOutputLevel);
|
|
}
|
|
|
|
@end
|