mirror of
https://github.com/mollyim/webrtc.git
synced 2025-05-14 06:10:40 +01:00
7bca8ca4e2
This CL separates the files under sdk/objc into logical directories, replacing the previous file layout under Framework/. A long term goal is to have some system set up to generate the files under sdk/objc/api (the PeerConnection API wrappers) from the C++ code. In the shorter term the goal is to abstract out shared concepts from these classes in order to make them as uniform as possible. The separation into base/, components/, and helpers/ are to differentiate between the base layer's common protocols, various utilities and the actual platform specific components. The old directory layout that resembled a framework's internal layout is not necessary, since it is generated by the framework target when building it. Bug: webrtc:9627 Change-Id: Ib084fd83f050ae980649ca99e841f4fb0580bd8f Reviewed-on: https://webrtc-review.googlesource.com/94142 Reviewed-by: Kári Helgason <kthelgason@webrtc.org> Reviewed-by: Mirko Bonadei <mbonadei@webrtc.org> Reviewed-by: Rasmus Brandt <brandtr@webrtc.org> Reviewed-by: Henrik Andreassson <henrika@webrtc.org> Commit-Queue: Anders Carlsson <andersc@webrtc.org> Cr-Commit-Position: refs/heads/master@{#24493}
57 lines
2.4 KiB
Text
57 lines
2.4 KiB
Text
/*
|
|
* Copyright 2017 The WebRTC project authors. All Rights Reserved.
|
|
*
|
|
* Use of this source code is governed by a BSD-style license
|
|
* that can be found in the LICENSE file in the root of the source
|
|
* tree. An additional intellectual property rights grant can be found
|
|
* in the file PATENTS. All contributing project authors may
|
|
* be found in the AUTHORS file in the root of the source tree.
|
|
*/
|
|
|
|
#import "RTCRtpFragmentationHeader+Private.h"
|
|
|
|
#include "modules/include/module_common_types.h"
|
|
|
|
@implementation RTCRtpFragmentationHeader (Private)
|
|
|
|
- (instancetype)initWithNativeFragmentationHeader:
|
|
(const webrtc::RTPFragmentationHeader *)fragmentationHeader {
|
|
if (self = [super init]) {
|
|
if (fragmentationHeader) {
|
|
int count = fragmentationHeader->fragmentationVectorSize;
|
|
NSMutableArray *offsets = [NSMutableArray array];
|
|
NSMutableArray *lengths = [NSMutableArray array];
|
|
NSMutableArray *timeDiffs = [NSMutableArray array];
|
|
NSMutableArray *plTypes = [NSMutableArray array];
|
|
for (int i = 0; i < count; ++i) {
|
|
[offsets addObject:@(fragmentationHeader->fragmentationOffset[i])];
|
|
[lengths addObject:@(fragmentationHeader->fragmentationLength[i])];
|
|
[timeDiffs addObject:@(fragmentationHeader->fragmentationTimeDiff[i])];
|
|
[plTypes addObject:@(fragmentationHeader->fragmentationPlType[i])];
|
|
}
|
|
self.fragmentationOffset = [offsets copy];
|
|
self.fragmentationLength = [lengths copy];
|
|
self.fragmentationTimeDiff = [timeDiffs copy];
|
|
self.fragmentationPlType = [plTypes copy];
|
|
}
|
|
}
|
|
|
|
return self;
|
|
}
|
|
|
|
- (std::unique_ptr<webrtc::RTPFragmentationHeader>)createNativeFragmentationHeader {
|
|
auto fragmentationHeader =
|
|
std::unique_ptr<webrtc::RTPFragmentationHeader>(new webrtc::RTPFragmentationHeader);
|
|
fragmentationHeader->VerifyAndAllocateFragmentationHeader(self.fragmentationOffset.count);
|
|
for (NSUInteger i = 0; i < self.fragmentationOffset.count; ++i) {
|
|
fragmentationHeader->fragmentationOffset[i] = (size_t)self.fragmentationOffset[i].unsignedIntValue;
|
|
fragmentationHeader->fragmentationLength[i] = (size_t)self.fragmentationLength[i].unsignedIntValue;
|
|
fragmentationHeader->fragmentationTimeDiff[i] =
|
|
(uint16_t)self.fragmentationOffset[i].unsignedIntValue;
|
|
fragmentationHeader->fragmentationPlType[i] = (uint8_t)self.fragmentationOffset[i].unsignedIntValue;
|
|
}
|
|
|
|
return fragmentationHeader;
|
|
}
|
|
|
|
@end
|