mirror of
https://github.com/mollyim/webrtc.git
synced 2025-05-15 23:01:21 +01:00
7bca8ca4e2
This CL separates the files under sdk/objc into logical directories, replacing the previous file layout under Framework/. A long term goal is to have some system set up to generate the files under sdk/objc/api (the PeerConnection API wrappers) from the C++ code. In the shorter term the goal is to abstract out shared concepts from these classes in order to make them as uniform as possible. The separation into base/, components/, and helpers/ are to differentiate between the base layer's common protocols, various utilities and the actual platform specific components. The old directory layout that resembled a framework's internal layout is not necessary, since it is generated by the framework target when building it. Bug: webrtc:9627 Change-Id: Ib084fd83f050ae980649ca99e841f4fb0580bd8f Reviewed-on: https://webrtc-review.googlesource.com/94142 Reviewed-by: Kári Helgason <kthelgason@webrtc.org> Reviewed-by: Mirko Bonadei <mbonadei@webrtc.org> Reviewed-by: Rasmus Brandt <brandtr@webrtc.org> Reviewed-by: Henrik Andreassson <henrika@webrtc.org> Commit-Queue: Anders Carlsson <andersc@webrtc.org> Cr-Commit-Position: refs/heads/master@{#24493}
105 lines
3 KiB
Text
105 lines
3 KiB
Text
/*
|
|
* Copyright 2016 The WebRTC project authors. All Rights Reserved.
|
|
*
|
|
* Use of this source code is governed by a BSD-style license
|
|
* that can be found in the LICENSE file in the root of the source
|
|
* tree. An additional intellectual property rights grant can be found
|
|
* in the file PATENTS. All contributing project authors may
|
|
* be found in the AUTHORS file in the root of the source tree.
|
|
*/
|
|
|
|
#import "RTCRtpSender+Private.h"
|
|
|
|
#import "RTCDtmfSender+Private.h"
|
|
#import "RTCMediaStreamTrack+Private.h"
|
|
#import "RTCRtpParameters+Private.h"
|
|
#import "base/RTCLogging.h"
|
|
#import "helpers/NSString+StdString.h"
|
|
|
|
#include "api/mediastreaminterface.h"
|
|
|
|
@implementation RTCRtpSender {
|
|
RTCPeerConnectionFactory *_factory;
|
|
rtc::scoped_refptr<webrtc::RtpSenderInterface> _nativeRtpSender;
|
|
}
|
|
|
|
@synthesize dtmfSender = _dtmfSender;
|
|
|
|
- (NSString *)senderId {
|
|
return [NSString stringForStdString:_nativeRtpSender->id()];
|
|
}
|
|
|
|
- (RTCRtpParameters *)parameters {
|
|
return [[RTCRtpParameters alloc]
|
|
initWithNativeParameters:_nativeRtpSender->GetParameters()];
|
|
}
|
|
|
|
- (void)setParameters:(RTCRtpParameters *)parameters {
|
|
if (!_nativeRtpSender->SetParameters(parameters.nativeParameters).ok()) {
|
|
RTCLogError(@"RTCRtpSender(%p): Failed to set parameters: %@", self,
|
|
parameters);
|
|
}
|
|
}
|
|
|
|
- (RTCMediaStreamTrack *)track {
|
|
rtc::scoped_refptr<webrtc::MediaStreamTrackInterface> nativeTrack(
|
|
_nativeRtpSender->track());
|
|
if (nativeTrack) {
|
|
return [RTCMediaStreamTrack mediaTrackForNativeTrack:nativeTrack factory:_factory];
|
|
}
|
|
return nil;
|
|
}
|
|
|
|
- (void)setTrack:(RTCMediaStreamTrack *)track {
|
|
if (!_nativeRtpSender->SetTrack(track.nativeTrack)) {
|
|
RTCLogError(@"RTCRtpSender(%p): Failed to set track %@", self, track);
|
|
}
|
|
}
|
|
|
|
- (NSString *)description {
|
|
return [NSString stringWithFormat:@"RTCRtpSender {\n senderId: %@\n}",
|
|
self.senderId];
|
|
}
|
|
|
|
- (BOOL)isEqual:(id)object {
|
|
if (self == object) {
|
|
return YES;
|
|
}
|
|
if (object == nil) {
|
|
return NO;
|
|
}
|
|
if (![object isMemberOfClass:[self class]]) {
|
|
return NO;
|
|
}
|
|
RTCRtpSender *sender = (RTCRtpSender *)object;
|
|
return _nativeRtpSender == sender.nativeRtpSender;
|
|
}
|
|
|
|
- (NSUInteger)hash {
|
|
return (NSUInteger)_nativeRtpSender.get();
|
|
}
|
|
|
|
#pragma mark - Private
|
|
|
|
- (rtc::scoped_refptr<webrtc::RtpSenderInterface>)nativeRtpSender {
|
|
return _nativeRtpSender;
|
|
}
|
|
|
|
- (instancetype)initWithFactory:(RTCPeerConnectionFactory *)factory
|
|
nativeRtpSender:(rtc::scoped_refptr<webrtc::RtpSenderInterface>)nativeRtpSender {
|
|
NSParameterAssert(factory);
|
|
NSParameterAssert(nativeRtpSender);
|
|
if (self = [super init]) {
|
|
_factory = factory;
|
|
_nativeRtpSender = nativeRtpSender;
|
|
rtc::scoped_refptr<webrtc::DtmfSenderInterface> nativeDtmfSender(
|
|
_nativeRtpSender->GetDtmfSender());
|
|
if (nativeDtmfSender) {
|
|
_dtmfSender = [[RTCDtmfSender alloc] initWithNativeDtmfSender:nativeDtmfSender];
|
|
}
|
|
RTCLogInfo(@"RTCRtpSender(%p): created sender: %@", self, self.description);
|
|
}
|
|
return self;
|
|
}
|
|
|
|
@end
|